Pada artikel ini akan diberikan contoh Cara Backup mikrotik dan kirim konfig ke email contohnya Gmail secara berkala dan otomatis. Secara teknis kebutuhan tersebut dapat di penuhi dengan menggunakan kombinasi beberapa perintah.

Melakukan backup konfigurasi pada Router adalah hal sangat bijak yang dapat anda lakukan agar router anda tidak perlu melakukan config ulang pada saat router ter-reset atau crash. Untuk melakukan backup secara rutin kita bisa melakukannya dengan mengirimkan file ke alamat email anda, khususnya GMAIL

Cara Backup mikrotik dan kirim konfig keg email

silahkan gunakan script backup yang dapat di jalankan setiap hari. langkah-langkahnya adalah sebagai berikut

Buka Winbox dan klik System script

1. kita akan memanfaatkan SMTP bawaan GMAIL untuk mengirim email ke anda.
2. buka system -> script -> tambahkan script baru dengan nama backup

untuk policy silahkan di centang semuanya seperti gambar diatas.

Script backup

lalu isikan script source sebagai berikut:

#### Modify these values to match your requirements ####
 
#Your email address to receive the backups
:local toemail "alamat[at]gmailanda.com"
 
#The From address (you can use your own address if you want)
:local fromemail "alamat[at]gmailanda.com"
 
#A mail server your machines can send through
:local emailserver "74.125.200.108"
 
:local password "PasswordGmailAnda"
 
############## Don’t edit below this line ##############
 
 
:local sysname [/system identity get name]
:local textfilename
:local backupfilename
:local time [/system clock get time]
:local date [/system clock get date]
:local newdate "";
:for i from=0 to=([:len $date]-1) do={ :local tmp [:pick $date $i];
:if ($tmp !="/") do={ :set newdate "$newdate$tmp" }
:if ($tmp ="/") do={}
}
#check for spaces in system identity to replace with underscores
:if ([:find $sysname " "] !=0) do={
:local name $sysname;
:local newname "";
:for i from=0 to=([:len $name]-1) do={ :local tmp [:pick $name $i];
:if ($tmp !=" ") do={ :set newname "$newname$tmp" }
:if ($tmp =" ") do={ :set newname "$newname_" }
}
:set sysname $newname;
}
:set textfilename ($"newdate" . "-" . $"sysname" . ".rsc")
:set backupfilename ($"newdate" . "-" . $"sysname" . ".backup")
:execute [/export file=$"textfilename"]
:execute [/system backup save name=$"backupfilename"]
#Allow time for export to complete
:delay 2s
 
 
#email copies
:log info "Emailing backups"
/tool e-mail send to=$"toemail" from=$"fromemail" start-tls=yes port=587 subject="[Mikrotik Backup Export] $sysname $time" file=$"textfilename" user=$"fromemail" password=$"password"
#Send as different subjects to force GMail to treat as new message thread.
:local time [/system clock get time]
/tool e-mail send to=$"toemail" from=$"fromemail" start-tls=yes port=587 subject="[Mikrotik Backup] $sysname $time" file=$"backupfilename" user=$"fromemail" password=$"password"
 
#Allow time to send
:delay 10s
 
#delete copies
/file remove $textfilename
/file remove $backupfilename

pastikan warna baris 4,7,10,12 yang kami highlight diganti dengan detail login account GMAIL anda. lalu selanjutnya

Scheduler Mikrotik

buka system -> scheduler -> buat schedule baru dengan nama backup
untuk start date silahkan isikan tanggal hari ini, start time isikan jam berapa script mau di eksekusi, interval isikan 1d 00:00:00 yang artinya setiap 1 hari script akan running.
on event: backup
policy: centang semuanya lalu klik apply & OK.

Tools Mikrotik

selanjutnya buka tools -> email dan isikan dan simpan seperti dibawah ini:

server: 74.125.200.108
port: 587
start TLS: yes
from: <>
user: alamat[at]gmailanda.com
pass: PasswordGmailAnda

Periksa apakah script sudah berjalan dengan baik?

selanjutnya silahkan tunggu dan pastikan scheduler berjalan dengan baik dengan melihat kolom "run count" yang artinya scheduler anda sudah running.

Troubleshooting

jika error atau tidak menerima email sama sekali, jangan bingung! jangan lupa untuk Allow less secure apps pada akun GMAIL anda dengan cara seperti dibawah ini

Periksa hasil backup pada email anda

Lihat hasilnya pada email anda yang telah di daftarkan, pastikan akan sesuai dengan gambar dibawah ini

sekian tutorial singkat Cara Backup mikrotik dan kirim konfig ke email GMAIL dari kami

semoga bermanfaat.